Amortissement et mensualités d’un prêt

Renée De Graeve

2019

Voici le programme Amortissement(P,ta,na,S,periode="a") qui permet de connaître soit :

la somme S qu’il faut rembourser mensuellement (ou trimestrielement ou annuellement) lorsqu’on fait un prêt d’un montant P sur une durée de na ans au taux annuel ta. On tape pour avoir le montant S :
Amortissement(P,ta,na,-1,"m")[0] ("m" pour mois) ou
Amortissement(P,ta,na,-1,"t")[0] ("t" pour trimestre) ou
Amortissement(P,ta,na,-1,"a")[0]("a" pour an)
le montant du prêt P d’une durée de na ans au taux annuel ta qu’on rembourse mensuellement (ou trimestrielement ou annuellement) par une somme S.
On tape pour avoir le montant P :
Amortissement(-1,ta,na,S,"m")[0] ou
Amortissement(-1,ta,na,S,"t")[0] ou
Amortissement(-1,ta,na,S,"a")[0]
le taux ta d’un prêt P d’une durée de na ans qu’on rembourse mensuellement (ou trimestrielement ou annuellement) par une somme S.
On tape pour avoir le taux ta :
Amortissement(P,-1,na,S,"m")[0] ou
Amortissement(P,-1,na,S,"t")[0] ou
Amortissement(P,-1,na,S,"a")[0]
la durée na d’un prêt P au taux annuel ta que l’on rembourse mensuellement (ou trimestrielement ou annuellement) par une somme S.
On tape pour avoir la durée na :
Amortissement(P,ta,-1,S,"m")[0] ou
Amortissement(P,ta,-1,S,"t")[0] ou
Amortissement(P,ta,-1,S,"a")[0]
le montant qui reste à rembourser avant le $n$ ième remboursement, on tape :
Amortissement(P,ta,na,-1,"m")[n] ou
Amortissement(P,ta,na,-1,"t")[n] ou
Amortissement(P,ta,na,-1,"a")[n]
On obtient [n,Pn,An,In,S] où Pn est la somme qui reste à rembourser avant le $n$ ième remboursement.
Le $n$ ième remboursement S est égal à la somme de l’amortissement An et des intérêts In. Ainsi après le $n$ ième remboursement il restera Pn-An à rembourser.
le tableau d’amortissement d’une année.
Par exemple:
pour avoir le tableau d’amortissement de la première année, on tape :
Amortissement(P,ta,na,-1,"m")[1..12] ou
Amortissement(P,ta,na,-1,"t")[1..4] ou
Amortissement(P,ta,na,-1,"a")[1]
pour avoir le tableau d’amortissement de la deuxième année, on tape:
Amortissement(P,ta,na,-1,"m")[13..24] ou
Amortissement(P,ta,na,-1,"t")[5..8] ou
Amortissement(P,ta,na,-1,"a")[2]

Un exemple, pour un prêt de 10000 euros sur 5 ans au taux de 1.3% qui se rembourse à la fin de chaque année, on tape :

Amortissement(10000,0.013,5,-1,"a")[1..5]

On obtient [[1,P,A1,I1,S],[2,P-A1,A2,I2,S],...[5,P-A1-A2-A3-A4,A5,I5,S5]]
le montant du prêt P, l’amortissement A1 du prêt et les intérêts I1 constituant le 1ier remboursement (S=A1+I1=2078.67) puis [2,P-A1,A2,I2,S] etc...
Au bout des 5 ans, à cause des erreurs d’arrondis la somme à rembourser est de S5=2078.69 au lieu de S=2078.67.
On tape :

Amortissement(P,ta,na,S,periode="a"):={
  local n,t,j,MA,L,k,c,msg;
  k:=member(-1,[P,ta,na,S]);
  si periode=="m" alors n:=na*12;t:=ta/12;c:=12  
  sinon si periode=="t" alors n:=na*4;t:=ta/4;c:=4  
        sinon n:=na;t:=ta;c:=1;periode:="a";
        fsi; 
  fsi;
  si count_eq(-1,[P,ta,na,S,periode])!=1 alors 
    retourne("il faut mettre 3 arguments parmi P,ta,na,S") 
  fsi;
  si k==1 alors P:=Pret(t,n,S); 
  sinon  
    si k==2 alors t:=Taux(P,n,S);ta:=round(t*c,4);
    sinon 
      si k==3 alors n:=Duree(P,t,S);
      sinon S:=Sommes(P,t,n); 
      fsi;
    fsi;
  fsi; 
  msg:="Pret "+P+", taux annuel "+ ta+ ", pendant "+ n +periode +" : "+S;
 afficher(msg);
  MA:=NULL;
  pour j de 0 jusque n-1 faire
    MA:=MA,[j+1,P,round(S-P*t,2),round(P*t,2),S];
    P:=round(P*(1+t)-S,2);
  fpour;
  MA[n-1]:=MA[n-1]+[0,0,P,0,P];
  return [msg,MA];
 }:;
Duree(P,t,S):=round((ln(S)-ln(S-t*P))/ln(1+t),0):;
Sommes(P,t,n):=round(P*t*(1+1/((1+t)^n-1)),2):;
Pret(t,n,S):=round(S/t*(1-1/(1+t)^n),2):;
Taux(P,n,S):=resoudre_numerique(S*((1+x)^n-1)-P*(1+x)^n*x=0,x=1):;

onload