Previous Up Next

5  Représentations graphiques

Pour obtenir une représentation graphique dans Xcas, il faut saisir une commande dont la sortie est un objet graphique. Pour vous aider à effectuer les représentations graphiques les plus courantes, le menu Graphic vous propose des boites de dialogue qui se chargent de créer une ligne de commande et de le valider pour afficher le graphique souhaité.

Si vous souhaitez représenter plusieurs objets graphiques dans une même représentation, vous devez séparer les commandes les créant par un ;. Vous pouvez aussi créer une figure (menu Geo, Nouvelle figure) et utiliser le menu Geo pour créer des objets géométriques.

Chaque commande graphique crée un objet graphique 2-d ou 3-d, qui est traduit en réponse par une image dans la fenêtre Xcas. A droite de cette image, des boutons de zoom in et out permettent d’agrandir ou de rapetisser la représentation, des flèches permettent de la déplacer.

Les paramètres par défaut (en particulier les intervalles de représentation en abscisse et ordonnée) peuvent être changés dans la fenêtre de configuration graphique accessible depuis le menu Cfg->Configuration graphique.

Notez enfin que les objets graphiques 2-d sont aussi affichés dans une fenêtre appelée DispG (Display Graphics) que vous pouvez faire apparaître par le menu Cfg->Montrer->DispG ou avec la commande DispG. La différence est que les graphiques successifs sont tracés individuellement dans chaque fenêtre de réponse, alors qu’ils sont superposés dans la fenêtre DispG. Vous pouvez effacer la fenêtre DispG par la commande ClrGraph.

5.1  Tracés de courbes

Pour créer rapidement des tracés de courbes simples, il est conseillé d’utiliser le menu Graphic.

L’instruction de tracé d’une courbe représentative de fonction est plot avec en paramètres une expression ou une liste d’expressions dont on veut la représentation graphique, puis la variable (éventuellement on indique l’intervalle de valeurs de la variable). Pour distinguer plusieurs courbes, on peut utiliser un troisième argument par exemple couleur= suivi de la liste des couleurs à utiliser. Les couleurs peuvent être codées par leur nom français, leur nom anglais ou leur numéro. La fonction couleur change la couleur de base pour toutes les fonctions graphiques qui suivent. La fonction tangent permet d’obtenir la tangente à une courbe en un point.

E:=(2*x+1)/(x^2+1);plot(E)
plot(E,x=-2..2,color=red)
couleur(vert);plot(E,couleur=rouge);tangent(plot(E),0)
DispG()
plot([sin(x),x,x-x^3/6],x=-2..2,couleur=[rouge,bleu,vert])
erase
li:=[(x+k*0.5)^2$(k=-5..5)]:;
plot(li,x=-8..8,couleur=[k$(k=0..10)])

La fonction plotparam permet d’effectuer le tracé de (x(t),y(t)). Il faut définir les deux coordonnées comme une seule expression complexe dont x(t) est la partie réelle et y(t) la partie imaginaire. La fonction plotpolar trace les courbes en coordonnées polaires. La commande plotimplicit(f(x,y),x,y) trace l’ensemble des solutions de f(x,y)=0.

plotparam(sin(t)^3+i*cos(t)^3,t,0,2*pi)
plotparam(t^2+i*t^3,t,-1,1)
plotpolar(1/(1-2sin(t/2)),t,0,4*pi)
plotpolar(tan(t)+tan(t/2),t,0,2*pi)
plotimplicit(x^2+4*y^2-4,x,y)
Tracés de courbes
plotgraphe d’une expression d’une variable
plotfuncgraphe d’une expression d’1 ou 2 variable(s)
couleurchoisir la couleur d’un tracé
tangenttangente à une courbe
plotparamcourbe paramétrique
plotpolarcourbe en polaires
plotimplicitcourbe implicite

5.2  Objets graphiques 2D

Xcas étant aussi un logiciel de géométrie plane, de nombreuses figures peuvent être tracées (dans un écran que l’on obtient avec Alt+g) par des commandes du menu Geo, par exemple des polygones, des coniques…  Les arguments de ces commandes sont souvent des points (commande point) qui peuvent en général être saisis directement par leur affixe complexe. Par exemple cercle(2+3*i,2) trace le cercle centré au point (2,3), de rayon 2. La commande legende permet de placer un texte à un endroit, lui aussi spécifié par un nombre complexe. Les fonctions polygonplot et scatterplot prennent en entrée une liste d’abscisses et une liste d’ordonnées.

lx:=[k$(k=1..10)]
ly:=apply(sin,lx)
polygonplot(lx,ly)
erase
scatterplot(lx,ly)
polygone_ouvert(lx+i*ly)
Objets graphiques 2D
legendmet du texte à partir d’un point donné
pointpoint donné par son affixe ou 2 coordonnées
segmentsegment donnée par 2 points
droitedroite donnée par son équation ou 2 points
cerclecercle donnée par centre et rayon
interintersection de courbes
equationéquation cartésienne
parameqéquation paramétrique
polygonplotligne polygonale
scatterplotnuage de points
polygonepolygone fermé
polygone_ouvertpolygone ouvert

5.3  Objets graphiques 3D

Objets graphiques 3D
plotfuncsurface par équation
plotparamsurface ou courbe paramétrique
pointpoint donné par 3 coordonnées
droitedroite donnée par 2 équations ou 2 points
planplan donné par 1 équation ou 3 points
spheresphère donnée par centre et rayon
conecone donné par centre, axe, angle d’ouverture
interintersection
polygonepolygone
polygone_ouvertpolygone ouvert


Previous Up Next