Les variables locales symboliques

Attention Les variables locales sont toujours affectèes, par exemple :
local A;
print(A);
affichera A:0 écrit en bleu.
Si on veut utiliser dans un programme des variables formelles, on a 2 solutions :

• On considère les variables formelles du programme comme globales, MAIS alors il faut s'assurer que ces variables sont purgées avant l'exécution du programme...ce qui contraignant !

• On déclare les variables formelles du programme avec local (par exemple local x;), PUIS on utilise assume(x,symbol); pour spécifier que la variable x devient symmbolique ou on utilise purge(x) pour purger la variable x qui devient symmbolique. Ainsi au cours du programme, x pourra devenir non symbolique si on l'affecte, puis, redevenir symbolique après l'instruction assume(x,symbol); ou l'instruction purge(x).

Il est donc préférable de définir la variable formelle var, avec local var; suivi de assume(var,symbol); ou de purge(var).
Exemple
Voici le programme qui donne la valeur de la suite de Fibonnacci u définie par u₀ = u0, u₁ = u1, u_n+2 = u_n+1 + u_n.
On sait que si a et b sont les racines de x² - x - 1, les suites vérifiant la relation de récurrence u_n+2 = u_n+1 + u_n sont des combinaisons linéaires des suites géométriques aⁿ et bⁿ, c'est-à-dire que l'on a :

u_n = Aaⁿ + Bbⁿ

pour A et B solutions du système [u₀ = A + B, u₁ = Aa + Bb].

Voici les deux façons de faire :

• les variables formelles sont globales,
  Dans le programme qui suit, on utilise les variables formelles x,A,B qui doivent être purgées et qui seront des variables globales.
  On tape :

  u(n,uo,u1):={
  local L,a,b;
  //verifier que A,B,x ne sont pas affectées
  [a,b]:=solve(x^2-x-1,x);
  L:=linsolve([A+B=uo,A*a+B*b=u1],[A,B]);
  return normal(L[0]*a^n+L[1]*b^n);
  };
  

  Lors de la compliation, Xcas dit :
  //Warning: x A B declared as global variable(s)
  compiling u
  On tape :
  u(3,0,1)
  On obtient :
  2
  
• les variables formelles sont declarées locales,
  Dans le programme qui suit, on utilise les variables formelles A,B,x qui seront symboliques ou formelles grâce aux commandes :

  assume(A,symbol);
  assume(B,symbol);
  assume(x,symbol);
  

  ou à la commande purge(A,B,x).

  Remarque : pour retrouver des variables non formelles il suffira de les affecter.
  On tape :

  u(n,uo,u1):={
  local L,a,b,A,B,x;
  assume(A,symbol);
  assume(B,symbol);
  assume(x,symbol);
  [a,b]:=solve(x^2-x-1,x);
  L:=linsolve([A+B=uo,A*a+B*b=u1],[A,B]);
  return normal(L[0]*a^n+L[1]*b^n);
  };
  

  Ou on tape :

  u(n,uo,u1):={
  local L,a,b,A,B,x;
  purge(A,B,x);
  [a,b]:=solve(x^2-x-1,x);
  L:=linsolve([A+B=uo,A*a+B*b=u1],[A,B]);
  return normal(L[0]*a^n+L[1]*b^n);
  };
  

  Lors de la compliation, Xcas dit :
  // Success compiling u
  On tape :
  u(3,0,1)
  On obtient :
  2
  Pour bien comprendre ce qui se passe, on rajoute des print :

  u(n,uo,u1):={
  local L,a,b,A,B,x;
  print(A);
  assume(A,symbol);
  print(A);
  assume(B,symbol);
  assume(x,symbol);
  [a,b]:=solve(x^2-x-1,x);
  L:=linsolve([A+B=uo,A*a+B*b=u1],[A,B]);
  A:=5;
  print(A);
  return normal(L[0]*a^n+L[1]*b^n);
  };
  

  On tape :
  A:=30
  u(3,0,1)
  On obtient écrit en bleu :
  A:0 (A est locale et n'est pas symbolique et vaut 0)
  A:A (A est locale et symbolique)
  A:5 (A est locale etn'est pas symbolique et vaut 5)
  puis la réponse :
  2
  On tape :
  A
  On obtient :
  30 (la variable globale A n'est pas symbolique et vaut 30)