\documentclass{article}
\usepackage[utf8]{inputenc}
\usepackage[T1]{fontenc}
\usepackage{amsmath}
\usepackage{amsfonts}
\usepackage{latexsym}
\usepackage{amssymb}
\usepackage{times}
\usepackage{ifpdf}
\usepackage{makeidx}
\usepackage{graphicx}
\ifpdf
 \usepackage[pdftex,colorlinks]{hyperref}
\else
 \usepackage[ps2pdf,breaklinks=true,colorlinks=true,linkcolor=red,citecolor=green]{hyperref}
 \fi

\newtheorem{rem}{Remark}
\newcommand{\R}{{\mathbb{R}}}
\newcommand{\C}{{\mathbb{C}}}
\newcommand{\Z}{{\mathbb{Z}}}
\newcommand{\N}{{\mathbb{N}}}
\newcommand{\Q}{{\mathbb{Q}}}
\newcommand{\atan}{{\mbox{atan}}}
%\newcommand{\faux}{$\square\;$}
%\newcommand{\vrai}{$\square\;$}
%\newtheorem{thm}{Theorem}
%\newtheorem{exo}{Exercice}[section]
\input{giac.tex}
\giacmathjax
\title{Le puzzle de Dudeney}

\author{Ren\'ee De Graeve}
\date{2017}
\begin{document}
\begin{giacjshere}
\maketitle
\tableofcontents
%puzzletri.xws puzzletritri2.xws animduden.xws
%carredudeney.xws
% cascas.tex
\section{Introduction}
Les quatre pi\`eces du puzzle de Dudeney permettent 
de construire un carr\'e ou un triangle \'equilat\'eral.
L'animation 1 ci-dessous l'illustre, 
appuyer sur {\bf +} puis sur {\bf -} pour passer de l'un \`a l'autre.\\
\giacslider{t}{-3.14}{0}{0.314}{-3.14}{gl_x=-6..6;gl_y=-4.2..3;animtri(t)}

Ernest Dudeney (1857-1930) a montr\'e ce puzzle en 1905 lors d'une s\'eance \`a 
la Royal Society \`a Londres.
Sur ce mod\'ele nous avons r\'ealis\'e ici d'autres puzzles de 4 pi\`eces  
qui transforment
\begin{enumerate}
\item un carr\'e en un triangle \'equilat\'eral (ci-dessus)
\item un carr\'e en un triangle isoc\`ele (animation 2 ci-dessous)
\item un rectangle en un triangle \'equilat\'eral (animation 3
ci-dessous)
\end{enumerate}

Voici l'animation 2 (vous pouvez changer la valeur 1.6 de $l$ en une valeur 
entre 0.27 et 2, vous pouvez aussi changer le pas de 0.01 en 0.1) :\\
\giacslider{t}{-3.14}{0}{0.314}{-3.14}{gl_x=-6..6;gl_y=-4.2..3;animtriso(t,1.6)}
Pour r\'ealiser une animation appuyer sur {\bf +} puis sur {\bf -} etc ...

Voici l'animation 3 (vous pouvez changer la valeur 1.6 de $a$ en une valeur 
entre 0.58 et 1.73, vous pouvez aussi changer le pas de 0.01 en 0.1) :\\
\giacslider{t}{-3.14}{0}{0.314}{-3.14}{gl_x=-6..6;gl_y=-4.2..3;animrectr(t,1.6)}
Pour r\'ealiser une animation appuyer sur {\bf +} puis sur {\bf -} etc ...


\section{Les 4 pi\`eces du puzzle}
%\includegraphics[width=\textwidth]{puzzlecan}\\
Voici la d\'ecomposition du carr\'e en 4 morceaux qui s'assemblent en formant
le triangle \'equilat\'eral $R_1RR_2$ :
\begin{giaconload}
A:=point(0);B:=point(2);C:=point(2+2*i);D:=point(2*i);
M:=milieu(A,B);N:=milieu(C,D);la:=evalf(sqrt(4*sqrt(3)/3-1));
P:=point(i*(2-la));Q:=point(2+i*la);R:=rotation(M,pi/3,Q);
segment(P,N);segment(R,Q);segment(R,M);
segment(M,Q);segment(M,P);segment(N,Q);
N1:=symetrie(Q,N);R1:=symetrie(Q,R);
R2:=symetrie(M,R);P2:=symetrie(M,P);
segment(Q,R1);segment(R1,R2);
segment(M,R2);segment(B,P2);
C1:=symetrie(Q,C);segment(N1,C1);
affichage(polygone(A,M,R,P),1+rempli);
affichage(triangle(N,D,P),2+rempli);
affichage(polygone(C,N,R,Q),3+rempli);
affichage(polygone(B,M,R,Q),4+rempli);
polygone(M,P,N,Q);
R:=R;Q:=Q;M:=M;B:=B;C:=C;
\end{giaconload}
Etant donn\'e un carr\'e, trouver la construction de ces pi\`eces et prouvez 
que l'on a  bien obtenu apr\`es r\'eorganisation un triangle \'equilat\'eral.\\
{\bf La solution}

%\includegraphics[width=\textwidth]{puzzlecatri}\\
{\bf Supposons le probl\`eme r\'esolu}\\
Si le carr\'e est de c\^ot\'e {\tt 2a} et le c\^ot\'e du triangle 
\'equilat\'eral est de c\^ot\'e {\tt 2b}.\\ 
On doit avoir (\'egalit\'e des aires) : $4a^2=b^2\sqrt 3$.\\
On voit que si les figures sont exactes pour obtenir un triangle \'equilat\'eral
\`a partir du carr\'e de c\^ot\'e {\tt 2a} il faut, sans bouger la pi\`ece 
bleue, faire subir :\\
- \`a la pi\`ece rouge une sym\'etrie par rapport \`a $M$ \\
- \`a la pi\`ece jaune une sym\'etrie par rapport \`a $Q$\\
- \`a la pi\`ece verte une translation de vecteur $NN_1$ ($N_1$ \'etant le 
sym\'etrique de $N$ par  rapport \`a $Q$).\\
Supposons que le triangle $R_1RR_2$ soit \'equilat\'eral.\\
On a alors :\\
$RQ=QR_1=b$, $RM=MR_2=b$, $MQ=R_1R_2/2=b$ et\\
Le triangle $RMQ$ est donc \'equilat\'eral.\\
$\widehat{QRN}=\widehat{QR_1N_1}=\pi/3$\\
$\widehat{PRM}=\widehat{P_2R_2M}=\widehat{QMR}=\pi/3$\\
Les droites $PN$, $MQ$ et $R_1R_2$ sont donc parall\`eles.\\
Puisque $PR=P_2R_2$, $RN=R_1N_1$ et $PN=P_2N_1$ on a :\\
$R_1R_2=2b=R_1N_1+N_1P_2+P_2R_2=RN+NP+PR=2NP$\\
Donc $NP=MQ=b$ et $MPNQ$ est un parall\'elogramme.\\
Puisque $PN=MQ$ et $DN=MB=a$, les triangles rectangles $DNP$ et $BMQ$ sont 
\'egaux, donc $PD=BQ$.\\
Les triangles rectangles $APM$ et $CQN$ sont aussi \'egaux ($AP=2a-l=CQ$).\\
On a :\\
$PN=MQ$ et $PM=NQ$ donc la quadrilat\`ere $MPNQ$ est un parall\'elogramme.\\
Puisque $RMQ$ est un triangle \'equilat\'eral de c\^ot\'e $b$, on en d\'eduit 
que la distance $h$  entre les parall\`eles  $PN$ et $MQ$ vaut $b\sqrt 3/2$
($h$ est la hauteur du triangle \'equilat\'eral $QRM$ de c\^ot\'e $b$).\\
{\bf Le point $R$} est donc l'intersection de la m\'ediatrice de $MQ$ avec 
$PN$ et il est aussi le transform\'e de $Q$ par la rotation de 
centre $M$ et d'angle $\pi/3$.\\
{\bf Calculons $l=PD=BQ$.}\\
Dans le triangle rectangle $DPN$, on a $PD=l$,$DN=a$ et $PN=b$,\\
 donc :\\
$b^2=PN^2=l^2+a^2=4a^2/\sqrt(3)$ donc  $l^2=b^2-a^2$\\
Donc $l^2=a^2(4\sqrt 3/3-1)$

{\bf La construction}\\
Lorsque $PD=l=2a\sqrt{(\sqrt 3/3-1)}$, construisons :\\
le carr\'e $ABCD$, \_
le milieu $M$ (resp $N$) de $AB$ (resp $CD$)\\
le point $P$ (resp $Q$) du segment $AD$ (resp $BC$) tel que $DP=l$ 
(resp($BQ=l$)\\
Le point $R$ intersection de la m\'ediatrice de $MQ$ avec $PN$\\
$R_2$ est le sym\'etrique de $R$ par rapport à $M$ et \\
$R_1$ est le sym\'etrique de $R$ par rapport à $Q$ donc\\
$MQ$ est parall\`ele \`a $R_1R_2=2b$ et $MQ=b$.\\
Les triangles rectangles $NDP$ et $MBQ$ sont donc \'egaux.\\
Donc  $PD=BQ=l$, $PN=MQ$ et $DN=MB$ \\
$A$ est le sym\'etrique de $B$ par rapport à $M$ donc $AM=MB=a$\\
donc $AM=MB=DN=NC=a$.\\
Les triangles rectangles $APM$ et $CQN$ sont aussi \'egaux ($AP=2a-l=CQ$).\\
On a :\\
$PN=MQ$ et $PM=NQ$ donc la quadrilat\`ere $MPNQ$ est un parall\'elogramme.\\
{\bf Remarque} \\
$MPNQ$ n'est pas un rectangle car $MP^2+NP^2\neq 4$ :\\
\giacinput{evalf(longueur2(M,P)+longueur2(N,P))} \\
On a donc :\\
L'aire des triangles rectangles $APM$ et $CQN$ plus l'aire des triangles
rectangles $NDP$ et $MBQ$ est \'egale \`a l'aire du rectangle $AMND$ c'est \`a 
dire est \`egale \`a $2a^2$.\\
L'aire du parall\'elogramme $MPNQ$ vaut donc $4a^2-2a^2=2a^2$.\\
Puisque $MQ=b$ on en d\'eduit que la distance $h$  entre les parall\`eles  $PN$ 
et $MQ$ vaut $2a^2/b=b\sqrt 3/2$ (puisque $4a^2=b^2\sqrt 3$).\\
$h$ est la hauteur du triangle isoc\`ele $RQM$ de base $QM=b$ donc\\
le triangle $QRM$ est \'equilat\'eral ($RQ^2=RM^2=h^2+(b/2)^2=b^2(3/4+1/4)=b^2$)

On tape pour avoir les pi\`eces du puzzle (on prend pour simplifier $a=1$) i.e. 
le carr\'e a des c\^ot\'es de longueur 2 :
\begin{giaconload}
fonction pieces()
local l,M,N,P,Q,R,L;
L:=NULL;
l:=evalf(sqrt(4*sqrt(3)/3-1));
M:=point(1);
N:=point(1+2*i);
P:=point(i*(2-l));
Q:=point(2+i*l);
R:=inter_unique(droite(P,N),mediatrice(M,Q));
L:=L,affichage(quadrilatere(M,2,Q,R),4+rempli); 
L:=L,affichage(quadrilatere(Q,2+2*i,1+2i,R),3+rempli); 
L:=L,affichage(triangle(P,2i,1+2i),2+rempli);
L:=L,affichage(quadrilatere(0,M,R,i*(2-l)),1+rempli); 
retourne L;
ffonction :;
\end{giaconload}
\giacinput{gl_ortho=1;pieces()}
\section{Le pavage correspondant au puzzle de Dudeney}
On tape les proc\'edures {\tt dudeney0} (la pi\`ece triangle est en bas \`a 
gauche) et {\tt dudeney1} (la pi\`ece triangle est en haut \`a droite) :
\begin{giaconload}
fonction dudeney0(z0)
local M,P,Q,R,l,L;
l:=sqrt(4*sqrt(3)/3-1);
M:=point(1+z0);
P:=point(2+i*(2-l)+z0);
Q:=evalf(point(i*l+z0));
L:=NULL;
R:=rotation(M,-pi/3,Q);
L:=L,affichage(quadrilatere(M,z0,Q,R),4+rempli); 
L:=L,affichage(quadrilatere(Q,2*i+z0,1+2*i+z0,R),3+rempli); 
L:=L,affichage(triangle(P,2+2i+z0,1+2*i+z0),2+rempli);
L:=L,affichage(quadrilatere(2+z0,M,R,i*(2-l)+z0+2),1+rempli); 
retourne L;
ffonction:;
fonction dudeney1(z0)
local M,N,P,Q,R,l,L;
l:=sqrt(4*sqrt(3)/3-1);
M:=point(1+z0+2*i);
N:=point(1+z0);
P:=point(i*(l)+z0);
Q:=evalf(point(2-i*l+2*i+z0));
L:=NULL;
R:=inter_unique(segment(P,N),mediatrice(M,Q));
L:=L,affichage(quadrilatere(M,2+z0+2*i,Q,R),4+rempli); 
L:=L,affichage(quadrilatere(Q,2+z0,1+z0,R),3+rempli); 
L:=L,affichage(triangle(P,z0,1+z0),2+rempli);
L:=L,affichage(quadrilatere(0+z0+2*i,M,R,i*(l)+z0),1+rempli); 
retourne L;
ffonction :;
\end{giaconload}

\giacinputbig{gl_ortho=1;axes=0;la:=evalf(sqrt(4*sqrt(3)/3-1));dudeney1(0),
dudeney0(-2*i),dudeney0(-2+2*i*(la-1)),dudeney1(-2-2*i+2*i*(la-1))}
\section{Pour animer la transformation}
\begin{giaconload}
fonction animtri(t)
local l,M,N,B,C,D1,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,P1;
l:=sqrt(4*sqrt(3.)/3-1);
B:=point(2);C:=point(2+2*i);
M:=point(1);N:=point(1+2*i);
P:=point(i*(2-l));
Q:=evalf(point(2+i*l));
R:=evalf(inter_unique(segment(P,N),mediatrice(M,Q)));
L:=NULL;
L:=L,affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,t,evalf(quadrilatere(M,2,Q,R))),4+rempli);
Q1:=rotation(M,t,Q);
R1:=rotation(M,t,R);
N1:=rotation(M,t,N);
B1:=rotation(M,t,B);
C1:=rotation(M,t,C);
D1:=rotation(Q1,t,rotation(M,t,point(2*i)));
P1:=rotation(Q1,t,rotation(M,t,P));
N2:=rotation(Q1,t,N1);
P3:=quadrilatere(Q1,R1,N1,C1);
L:=L,affichage(rotation(Q1,t,P3),3+rempli); 
P2:=triangle(P1,D1,N2);
L:=L,affichage(rotation(N2,t,P2),2+rempli);
return L;
ffonction:;
\end{giaconload}
Voici l'animation :\\
\giacslider{t}{-3.14}{0}{0.314}{-3.14}{gl_x=-6..6;gl_y=-4.2..3;animtri(t)}
Pour réaliser une animation appuyer sur {\bf +} puis sur {\bf -} etc ...

\section{Prolongement : transformer un carr\'e en un triangle isoc\`ele}
%puzzledud.xws&
On peut faire la m\^eme construction en faisant varier $l$ entre 0 et $2a$, avec
comme condition : le point $R$ se trouve sur le segment $PN$ si $l\neq 0)$.\\ 
On transformera ainsi, un carr\'e  de c\^ot\'e $2a$, en un triangle 
isoc\`ele de base $2b=\sqrt{a^2+l^2}$ et de hauteur $h=4a^2/b$.\\
On a $0<=l<=2$.\\
Si $l=0$, le point $R$ est l'intersection de la m\'ediatrice de $MB$ avec $DC$.\\
%$R$ a pour affixe $(3-4*l+3*l^2)/(2+2*l^2)+i*(4+l+l^3)/(2+2*l^2)$,
Si $l\neq 0$, pour que $R$ soit sur sur le segment $PN$ il faut que :\\
{\tt re(affixe(R)]} soit entre 0 et $a=1$ et \\
{\tt im(affixe(R)]} soit entre 0 et $2a=2$.\\
On choisit ici $a=1$ et on tape :
\begin{giaconload}
fonction affixeR()
local M,N,P,Q,R,l,zR;
purge(l);
M:=point(1);
N:=point(1+2*i);
P:=point(i*(2-l));
Q:=point(2+i*l);
R:=inter_unique(mediatrice(M,Q),droite(P,N));
zR:= affixe(R);
return simplify(re(zR)),simplify(im(zR));
ffonction :;
\end{giaconload}
\giacinput{xR,yR:=affixeR()}\\
\giacinputbig{solve((1>=xR and 2>=yR) and (l>=0 and 2>=l),l)}\\
%\giacinput{solve(yR<=2,l)}\\
puisque $0\leq l\leq 2=2a$,il faut donc choisir :
$(2-\sqrt 3)a\leq l \leq2a$.\\
Les triangles isoc\`eles ont comme base $b=\sqrt{a^2+l^2}$ et une aire de 
$a^2=h*b/2$ donc la hauteur $h$ vaut $h=2a^2/b$.\\
Soit $t=(\overrightarrow{MQ}\overrightarrow{MP})$. $\tan(t)=2h/b$ on a donc :\\
$\tan(t)=\frac{4a^2}{a^2+l^2}$ donc\\
$4/5\leq tan(t) \leq 4/(3-\sqrt 3)$ soit :\\
$\atan(4/5) \leq t \leq atan(4/(3-sqrt(3)))$.\\
Voici la fonction pour animer la transformation :
\begin{giaconload}
fonction animtransfo(l)
local M,N,B,C,D1,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,R2,P1;
B:=point(2);C:=point(2+2*i);
M:=point(1);N:=point(1+2*i);
P:=point(i*(2-l));
Q:=evalf(point(2+i*l));
R:=inter_unique(mediatrice(M,Q),droite(P,N));
L:=affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,pi,evalf(quadrilatere(M,0,P,R))),1+rempli);
N1:=symetrie(Q,N);R1:=symetrie(Q,R);
C1:=symetrie(Q,C);segment(N1,C1);
R1:=symetrie(Q,R);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
L:=L,affichage(polygone(2,M,R,Q),4+rempli);
L:=L,affichage(polygone(P,2*i,N),2+rempli);
L:=L,affichage(polygone(P2,C1,N1),2+rempli)
L:=L,affichage(polygone(0,P,R,,M),1+rempli); 
L:=L,affichage(polygone(B,P2,R2,,M),1+rempli); 
L:=L,affichage(polygone(N,R,Q,C),3+rempli);
L:=L,affichage(polygone(N1,R1,Q,C1),3+rempli);
return L;
ffonction:;
\end{giaconload}

 Voici l'animation quand $l$ varie entre 0 et 2 :\\
\giacslider{l}{0}{2}{0.1}{0}{gl_x=-3.5..5;gl_y=-2.2..2.9;animtransfo(l)}
Pour réaliser une animation appuyer sur {\bf +} puis sur {\bf -} etc ...
On voit que si $l$ est entre entre 0 et $2-\sqrt 3\simeq 0.267949192431$ ca ne 
marche pas ! Mais la construction reste valable pour $l=0$ (on notera dans ce 
cas la disparition du triangle vert).\\
On peut faire aussi l'animation qui transforme le carr\'e en un triangle 
isoc\`ele.\\
\begin{giaconload}
fonction animtriso(t,l)
local M,N,B,C,D1,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,P1;
//l:=sqrt(4*sqrt(3.)/3-1);
B:=point(2);C:=point(2+2*i);
M:=point(1);N:=point(1+2*i);
P:=point(i*(2-l));
Q:=evalf(point(2+i*l));
R:=evalf(inter_unique(segment(P,N),mediatrice(M,Q)));
L:=NULL;
L:=L,affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,t,evalf(quadrilatere(M,2,Q,R))),4+rempli);
Q1:=rotation(M,t,Q);
R1:=rotation(M,t,R);
N1:=rotation(M,t,N);
B1:=rotation(M,t,B);
C1:=rotation(M,t,C);
D1:=rotation(Q1,t,rotation(M,t,point(2*i)));
P1:=rotation(Q1,t,rotation(M,t,P));
N2:=rotation(Q1,t,N1);
P3:=quadrilatere(Q1,R1,N1,C1);
L:=L,affichage(rotation(Q1,t,P3),3+rempli); 
P2:=triangle(P1,D1,N2);
L:=L,affichage(rotation(N2,t,P2),2+rempli);
return L;
ffonction:;
\end{giaconload}
Voici l'animation (vous pouvez changer la valeur 1.6 de $l$ en une valeur entre 
0.27 et 2) :\\
\giacslider{t}{-3.14}{0}{0.314}{-3.14}{gl_x=-6..6;gl_y=-4.2..3;animtriso(t,1.6)}
Pour réaliser une animation appuyer sur {\bf +} puis sur {\bf -} etc ...

\section{Prolongement : transformer un rectangle en un triangle \'equilat\'eral}
Peut-on transformer un rectangle $c \times a$ en un triangle \'equilat\'eral 
avec la m\'ethode de Dudeney ?\\
On a vu pr\'ec\'edemment que pour que la m\'ethode de Dudeney fonctionne il 
fallait avoir soit $l=0$, soit le point $R$ sur le segment $PN$ ($R$ est 
l'intersection de la m\'ediatrice de $MQ$ et du segment $PN$, $MQNP$ est un 
parall\'elogramme et $MQ=L=\sqrt{c^+l^2}$).
\subsection{Valeur de $l$ pour transformer un rectangle $2c\times 2a$ en un triangle \'equilat\'eral}
Pour trouver la valeur de $l$ il suffit d'\'egaler la surface d'un triangle 
\'equilat\'eral de c\^ot\'e $b=\sqrt(c^2+l^2)$ avec la surface d'un rectangle de
 c\^ot\'e $c\times a$.\\
On doit donc avoir :\\ 
$b^2\sqrt 3/4=(c^2+l^2)\sqrt 3/4=ac$
Donc $l^2+c^2=4ac/\sqrt 3$ donc $l^2=c/\sqrt 3(4a-c\sqrt 3)$.\\
{\bf Cas particuler $l=0$}\\
$l=0$ est \'equivalent \`a  $a=c\sqrt 3/4$ et dans se cas le puzzle se 
r\'eduit \`a 3 pi\`eces :\\
%puzzledud.xws
On peut supposer, quitte \`a faire une homothetie, que $c=1$. 
\begin{giaconload}
fonction dudeneyrect0()
local a,l,M,N,B,C,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,R2,P1;
a:=sqrt(3)/4;l:=0;
B:=point(2);C:=point(2+2a*i);
M:=point(1);N:=point(1+2a*i);
P:=point(i*(2a-l)):;
Q:=evalf(point(2+i*l));
R:=inter_unique(mediatrice(M,Q),droite(P,N));
L:=NULL;
L:=L,affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,pi,evalf(quadrilatere(M,0,P,R))),1+rempli);
N1:=symetrie(Q,N);R1:=symetrie(Q,R);
C1:=symetrie(Q,C);segment(N1,C1);
R1:=symetrie(Q,R);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
L:=L,affichage(polygone(2,M,R,Q),4+rempli);
L:=L,affichage(polygone(P,2*a*i,N),2+rempli);
L:=L,affichage(polygone(P2,C1,N1),2+rempli)
L:=L,affichage(polygone(0,P,R,,M),1+rempli); 
L:=L,affichage(polygone(B,P2,R2,,M),1+rempli); 
L:=L,affichage(polygone(N,R,Q,C),3+rempli);
L:=L,affichage(polygone(N1,R1,Q,C1),3+rempli);
retourne L;
ffonction :;
\end{giaconload}
\giacinput{dudeneyrect0()}\\
\subsection{Les conditions sur $a$ et $c$}
Cherchons les conditions pour que $R$ soit entre $P$ et $N$.\\
Pour simplifier, on peut supposer, quitte \`a faire une homothetie que $c=1$.
Pour que $R$, d'affixe $xR+i*yR$, soit entre $P$ et $N$, il faut et il suffit
que :\\
 $ 0\leq xR \leq 1$ et $ 0\leq yR<2a$ \\  
Soit {\tt zP,zN,zQ,zM} les affixes de {\tt P,N,Q,M}.\\
Cherchons les coordonn\`ees $xR$ et $yR$ du point $R$, pour cela 
{\bf on demande \`a {\tt Xcas}} (on peut bien s\^ur faire les calculs \`a la 
main !) :
\begin{giaconload}
fonction coordR()
local P,Q,M,N,a,l2,l,R;
purge(a);
l2:=4a/sqrt(3)-1;
l:=sqrt(abs(l2));
P:=point((2a-l)*i);
Q:=point(2+l*i);
M:=point(1);
N:=point(1+2*a*i);
R:=inter_unique(droite(P,N),mediatrice(Q,M));
retourne coordonnees(R)
ffonction:;
\end{giaconload}
Puis on cherche les coordonn\'ees de $R$ et on r\'esout les in\'equations  
$0\leq xR \leq 1$ et $ 0\leq yR<2a$ ;\\:\\
\giacinputbig{xR,yR:=subst(coordR(),abs(4*a/sqrt(3)-1),4*a/sqrt(3)-1):;
simplify(solve(xR>= 0 and 1>=xR,a));simplify(solve(2a>=yR and yR>= 0,a));}\\
%\giacinputbig{l:=sqrt(4a/sqrt(3)-1);assume(a>sqrt(3)/4);xR,yR:=simplify(re(zR),im(zR))}\\
%\giacinputbig{simplify(solve((xR>= 0 and 1>=xR) and (yR>= 0 and 2a>=yR),a))}\\
Donc, puisque $\frac{\sqrt 3}{3}\leq a$ implique que $\frac{\sqrt 3}{4}\leq a$,
on pourra transformer un rectangle $1 \times a$ en un triangle \'equilat\'eral 
avec la m\'ethode de Dudeney si et seulement si on a :
$$\frac{\sqrt 3}{3}\leq a\leq \sqrt 3 )$$
ou encore :\\
On pourra transformer un rectangle $c \times a$ en un triangle \'equilat\'eral 
avec la m\'ethode de Dudeney si et seulement si on a :
$$\frac{c\sqrt 3}{3}\leq a \leq c\sqrt 3 $$
ou encore
$$\frac{c\sqrt 3}{3}\leq a \leq c\sqrt 3 $$ 
On pourra donc aussi transformer un rectangle $c \times a$ en un triangle 
\'equilat\'eral avec la m\'ethode de Dudeney si et seulement si on a :
$$\frac{a\sqrt3}{3}\leq c \leq a\sqrt 3 $$ 
ce qui signifie que l'on pourra avoir 2 puzzles diff\'erents.

{\bf Autre m\'ethode}
On choisit $a=3/2$, $c=1$ et $l=\sqrt{4a*c/\sqrt 3-c^2}\simeq 1.57$ 
\begin{giaconload}
Mr:=point(1);Qr:=point(2+1.57*i);
Nr:=point(1+3*i);Pr:=point((3-1.57)*i);
affichage(polygone(0,2,2+3*i,3*i),epaisseur_ligne_2);
affichage(polygone(Mr,Qr,Nr,Pr),epaisseur_ligne_2);
triangle_equilateral(Mr,Qr,Rr);
affichage(parallelogramme(Rr,Mr,Qr),1);
affichage(parallelogramme(Mr,Qr,Rr),4);
angle(Mr,Qr,Pr,"t");
affichage(angle(Qr,Rr,Mr,"\pi/3"),4);
\end{giaconload}
%affichage(angle(Mr,4/3+1.57*i/3,Rr,"\pi/3"),1);affichage(angle(Mr,5/3+2*1.57*i/3,Rr-1-1.57*i,"2\pi/3"),4);
%On a :\\
%\includegraphics[width=\textwidth]{condac}\\
Pour que la construction soit possible il faut que l'on puisse inscrire le 
triangle \'equilat\'eral $M_rQ_rR_r$ dans le parall\'elogramme $M_rQ_rN_rP_r$ : 
la hauteur $h$
Le triangle $MQR$ a comme c\^ot\'e $M_rQ_r=\sqrt{c^2+l^2}$ et comme hauteur 
$h=\sqrt{c^2+l^2}\sqrt 3/2$.\\
Il faut et il suffit que :\\
$\pi/3\leq t=\overrightarrow{M_rQ_r}\overrightarrow{M_rP_r}\leq 2\pi/3$
ce qui \'equivalent \`a :\\
$\sqrt(3)/2\leq \sin(t)\leq 1$\\
ce qui \'equivalent \`a :\\
$3/4\leq \sin(t)^2\leq 1$\\
On a  $MP^2=c^2+(2a-l)^2=4a^2-4al+l^2+c^2$ donc :\\
$\sin(t)^2=\frac{h^2}{MP^2}=\frac{3}{4}\frac{c^2+l^2}{4a^2-4al+l^2+c^2}$\\
La condition s'\'ecrit alors :\\
$\frac{3}{4}\leq \frac{3}{4}\frac{c^2+l^2}{4a^2-4al+l^2+c^2}$\\
$4a^2-4al+l^2+c^2\leq c^2+l^2$\\
ou encore :\\
$a\leq l$ et $a^2+c^2\leq l^2+c^2=4ac/\sqrt 3$\\
La condition devient donc :\\
$a^2-4ac/\sqrt 3+c^2\leq 0$\\
En posant $k=a/c$, il faut r\'esoudre l'in\'equation :\\
$k^2-4k/\sqrt 3 +1\leq 0$ donc il faut que $k$ soit compris entre les 2 racines 
de $k^2-4k/\sqrt 3 +1=0$ qui sont :\\
 $k1=1/\sqrt 3$ et $k2=\sqrt 3$.\\
La condition pour que le puzzle soit possible est donc :
$$\frac{1}{\sqrt 3}\leq \frac{a}{c}\leq \sqrt 3$$
ou encore :
$$\frac{c}{\sqrt 3}\leq a\leq c\sqrt 3c$$
\subsection{La transformation}
{\bf Cas g\'en\'eral $c/\sqrt 3\leq a\leq c\sqrt 3$ }\\
 $l$ est d\'efini par :\\
{\tt l=sqrt(4ac/sqrt(3)-c\verb|^|2)} car $4ac > 4c^2/\sqrt 3>c^2\sqrt 3$\\
On a alors :
$$l=\sqrt{\frac{4ac}{\sqrt 3}-c^2}$$ 
Lorsque le triangle $RMQ$ est \'equilat\'eral sa hauteur est :\\
$h=\sqrt{3(l^2+1)}/2$.\\
Donc lorsque le triangle $RMQ$ est \'equilat\'eral, la hauteur du 
paral\'ellogramme $MQNP$ est $h=\sqrt{3(l^2+1)}/2$.\\
Pour l'animation, on choisit $c=1$ et on fait varier $a$ entre $1/\sqrt 3$ et 
$\sqrt 3$ :
\begin{giaconload}
fonction dudeneyrect(a,c)
  local L,A,B,C,C1,D,M,N,N1,P,P2,Q,R,R1,R2,l; 
  l:=evalf(sqrt(4a*c/sqrt(3)-c^2));
  L:=NULL;  
  A:=point(0);  
  B:=point(2*c);  
  C:=point(2*c+2*a*i);  
  D:=point(2*a*i);  
  //polygone(A,B,C,D);  
  P:=point((2*a-l)*i);  
  Q:=point(2*c+l*i);  
  M:=point(c);  
  N:=point(c+2*a*i);  
  R:=inter_unique(mediatrice(M,Q),segment(N,P));  
  L:=L,affichage(triangle(D,P,N),2+rempli);  
  L:=L,affichage(polygone(A,P,R,M),1+rempli);  
  L:=L,affichage(polygone(C,N,R,Q),3+rempli);  
  L:=L,affichage(polygone(B,M,R,Q),4+rempli);  
  R2:=symetrie(M,R);  
  P2:=symetrie(M,P);  
  N1:=symetrie(Q,N);  
  C1:=symetrie(Q,C);  
  R1:=symetrie(Q,R);  
  L:=L,affichage(polygone(C1,N1,R1,Q),3+rempli);  
  L:=L,affichage(polygone(B,P2,R2,M),1+rempli);  
  L:=L,affichage(triangle(C1,P2,N1),2+rempli);  
  retourne L;  
ffonction :;
\end{giaconload}
On peut echanger le role de $a$ et $c$, on tape ($t$ d\'esigne une translation 
qui permet de faire les 2 dessins sur la m\^eme figure).
\begin{giaconload}
fonction dudeneyrect1(t,a,c)
 local L,A,B,C,C1,D,M,N,N1,P,P2,Q,R,R1,R2,l;
l:=evalf(sqrt(4a*c/sqrt(3)-c^2));
L:=NULL;    
A:=point(t);B:=point(t+2*c);C:=point(t+2c+2a*i);D:=point(t+2a*i);
//polygone(A,B,C,D);
P:=point(t+(2a-l)*i);Q:=point(t+2c+l*i);
M:=point(t+c);N:=point(t+c+2*a*i);
R:=inter_unique(mediatrice(M,Q),segment(N,P));
L:=L,affichage(triangle(D,P,N),2+rempli);
L:=L,affichage(polygone(A,P,R,M),3+rempli);
L:=L,affichage(polygone(C,N,R,Q),1+rempli);
L:=L,affichage(polygone(B,M,R,Q),4+rempli);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
N1:=symetrie(Q,N);
C1:=symetrie(Q,C);
R1:=symetrie(Q,R);
L:=L,affichage(polygone(C1,N1,R1,Q),1+rempli);
L:=L,affichage(polygone(B,P2,R2,M),3+rempli);
L:=L,affichage(triangle(C1,P2,N1),2+rempli);
retourne L;
ffonction :;
\end{giaconload}
 Voici l'animation :\\
\giacslider{k}{0.58}{1.73}{0.01}{0.58}{gl_x=-0.5..9.5;gl_y=-2.2..3.8;dudeneyrect(k,1),dudeneyrect1(4,1,k)}
Cela donne 2 puzzles diff\'erents (sauf lorsque $a=c$ ou $a=c\sqrt 3$ ou 
$a=c/\sqrt 3$).\\
Les voil\`a en superposition :\\
\begin{giaconload}
fonction dudeneyrect2(a,c) 
  local L1,L2,A,B,C,D,M1,M2,N2,N1,P1,P2,Q1,Q2,R1,R2,l1,l2;
  l1:=sqrt(4a*c/sqrt(3)-c^2);
  l2:=sqrt(4a*c/sqrt(3)-a^2);
  L1:=NULL; L2:=NULL; 
  A:=point(0);  
  B:=point(2*c);  
  C:=point(2*c+2*a*i);  
  D:=point(2*a*i);    
  P1:=point((2*a-l1)*i);  
  Q1:=point(2*c+l1*i);  
  M1:=point(c);  
  N1:=point(c+2*a*i);  
  R1:=inter_unique(mediatrice(M1,Q1),segment(N1,P1));  
  P2:=point(l2+2a*i);  
  Q2:=point(2c-l2);  
  M2:=point(2*c+a*i);  
  N2:=point(a*i);  
  R2:=inter_unique(mediatrice(M2,Q2),segment(N2,P2));  
  L1:=L1,polygone(M1,B,Q1,R1);
  L1:=L1,segment(P1,N1);
  L2:=L2,polygone(M2,B,Q2,R2);
  L2:=L2,segment(P2,N2);
  return affichage(L1,1),affichage(L2,4),polygone(A,B,C,D);
ffonction:;
\end{giaconload}
\giacslider{r}{0.58}{1.73}{0.01}{0.58}{gl_ortho=1;gl_x=-2..4;gl_y=-0.1..3.5;dudeneyrect2(r,1)}
On peut faire aussi l'animation qui transforme le rectangle en un triangle 
\'equilat\'eral.\\
\begin{giaconload}
fonction animrectr(t,a)
local l,M,N,B,C,D1,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,P1;
l:=evalf(sqrt(4a/sqrt(3)-1));
B:=point(2);C:=point(2+2a*i);
M:=point(1);N:=point(1+2a*i);
P:=point(i*(2a-l));
Q:=evalf(point(2+i*l));
R:=evalf(inter_unique(segment(P,N),mediatrice(M,Q)));
L:=NULL;
L:=L,affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,t,evalf(quadrilatere(M,2,Q,R))),4+rempli);
Q1:=rotation(M,t,Q);
R1:=rotation(M,t,R);
N1:=rotation(M,t,N);
B1:=rotation(M,t,B);
C1:=rotation(M,t,C);
D1:=rotation(Q1,t,rotation(M,t,point(2a*i)));
P1:=rotation(Q1,t,rotation(M,t,P));
N2:=rotation(Q1,t,N1);
P3:=quadrilatere(Q1,R1,N1,C1);
L:=L,affichage(rotation(Q1,t,P3),3+rempli); 
P2:=triangle(P1,D1,N2);
L:=L,affichage(rotation(N2,t,P2),2+rempli);
return L;
ffonction:;
\end{giaconload}
Voici l'animation (vous pouvez changer la valeur 1.6 de $a$ en une valeur entre 
0.58 et 1.73) :\\
\giacslider{t}{-3.14}{0}{0.314}{-3.14}{gl_x=-6..6;gl_y=-4.2..3;animrectr(t,1.6)}
Pour réaliser une animation appuyer sur {\bf +} puis sur {\bf -} etc ...

\end{giacjshere}
\end{document}
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

\begin{giaconload}
a:=3/2;c:=1;l1:=evalf(sqrt(4a*c/sqrt(3)-c^2));
M:=point(c);Q:=point(2c+l1*i);
N:=point(c+2a*i);P:=point((2a-l1)*i);
affichage(polygone(0,2c,2c+2a*i,2a*i),epaisseur_ligne_2);
affichage(polygone(M,Q,N,P),epaisseur_ligne_2);
triangle_equilateral(M,Q,R);
affichage(parallelogramme(R,M,Q),1);
affichage(parallelogramme(M,Q,R),4);
angle(M,Q,P,"t");
affichage(angle(M,4c/3+l1*i/3,R,"\pi/3"),1);
affichage(angle(M,5c/3+2*l1*i/3,R-1-l1*i,"2\pi/3"),4);
\end{giaconload}
\subsection{La transformation}
On peut transformer un rectangle en un triangle \'equilat\'eral avec la m\'ethode de Dudeney lorsque 
Essayons de transformer
\begin{giaconload}
fonction dudeneyrect(a,c=1):={
local L,A,B,C,C1,D,M,N,N1,R,R1,R2,P,P2,Q;
l:=sqrt(4*a*c/sqrt(3)-c^2);
L:=NULL;    
A:=point(0);B:=point(2c);C:=point(2c+2a*i);D:=point(2a*i);
polygone(A,B,C,D);
P:=point((2a-l)*i);Q:=point(2c+l*i);
M:=point(c);N:=point(c+2a*i);
R:=inter_unique(mediatrice(M,Q),segment(N,P));
L:=L,affichage(triangle(D,P,N),2+rempli);
L:=L,affichage(polygone(A,P,R,M),1+rempli);
L:=L,affichage(polygone(C,N,R,Q),3+rempli);
L:=L,affichage(polygone(B,M,R,Q),4+rempli);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
N1:=symetrie(Q,N);
C1:=symetrie(Q,C);
R1:=symetrie(Q,R);
L:=L,affichage(polygone(C1,N1,R1,Q),3+rempli);
L:=L,affichage(polygone(B,P2,R2,M),1+rempli);
L:=L,affichage(triangle(C1,P2,N1),2+rempli);
return L;
ffonction }:;
\end{giaconload}




\begin{giaconload}
animtransfog(t,a,c):={
local l,M,N,B,C,P,Q,R,Q1,N1,B1,C1,N2,P3,P2,L,B,C,R1,R2,P1,L;
l:=sqrt(4a/sqrt(3)-1);
L:=NULL;
B:=point(t+2);C:=point(t+2+2a*i);
M:=point(t+1);N:=point(t+1+2a*i);
P:=point(t+i*(2a-l));
Q:=evalf(point(t+2+i*l));
R:=inter_unique(mediatrice(M,Q),(P,N));
L:=affichage(quadrilatere(M,0,P,R),1+rempli); 
L:=L,affichage(rotation(M,pi,evalf(quadrilatere(M,0,P,R))),1+rempli);
N1:=symetrie(Q,N);R1:=symetrie(Q,R);
C1:=symetrie(Q,C);segment(N1,C1);
R1:=symetrie(Q,R);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
L:=L,affichage(polygone(2,M,R,Q),4+rempli);
L:=L,affichage(polygone(P,2*a*i,N),2+rempli);
L:=L,affichage(polygone(P2,C1,N1),2+rempli)
L:=L,affichage(polygone(0,P,R,,M),1+rempli); 
L:=L,affichage(polygone(B,P2,R2,,M),1+rempli); 
L:=L,affichage(polygone(N,R,Q,C),3+rempli);
L:=L,affichage(polygone(N1,R1,Q,C1),3+rempli);
return L;
 }:;
\end{giaconload}
\subsection{Un lemme}
Soit un parall\'elogramme $ABCD$, de c\^ot\'e $AB=L$, 
d'angle $t=(\overrightarrow{AB},\overrightarrow{AD})$ et de hauteur $DH=h$.
Quelle condition doit \^etre v\'erifi\'ee par $L,t,h$ pour que la m\'ediatrice 
de $AB$ coupe le segment $CD$ ? 
\begin{giaconload}
fonction Parallelogramme(a,L,t,h)
local A,B,C,D,M,H,k;
si t==0 alors retourne "erreur" fsi;
A:=point(a);
B:=tanslation(L,A);
si t-pi/2==0 alors k:=0 sinon k:=h/tan(t);fsi
D:=point(a+k+i*h);
C:=translation(L,D);
H:=point(a+k);
return (polygone(A,B,C,D),A,B,C,D,H);
ffonction:;
\end{giaconload}
\giacinputbig{P[0];[A,B,C,D,M,H]:=P[1];segment(D,H);segment(D,H);
P1[0];[A1,B1,C1,D1,M1,H1]:=P1[1];segment(D1,H1);segment(C1,H1+2);}\\
On voit donc que dans le cas du rectangle  i.e. si $t$ est \'egal \`a $\pi/2$
la m\'ediatrice de $AB$ coupe toujours le segment $CD$\\ 
Lorsque $t<\pi/2$,  la m\'ediatrice de $AB$ coupe le segment $CD$ si 
$AM=L/2>AH=k=h/\tan(t)$ (on a $\tan(t)>0$)
Lorsque $t>\pi/2$,  la m\'ediatrice de $A1B1$ coupe le segment $C1D1$ si 
$A1M1=L/2<L-H2B1=2L-k=L-h/\tan(pi-t)=L+h/tan(t)$ soit :\\
$-h/tan(t)<L/2$ (on a $\tan(t)<0$)
La condition pour que la m\'ediatrice de $AB$ coupe le segment $CD$ est donc:\\
 $2h/abs(\tan(t))<L$\\
{\bf Application au parall\'elogramme  $MQNP$}\\
On a :\\
$L=\sqrt{l^2+c^2}$\\
$h=\sqrt{l^2+c^2}\sqrt 3/2$ puisque $h$ est aussi la hauteur du triangle 
\'equilat\'eral $RMQ$ de c\^ot\'e $L$.\\
Posons $t=\overrightarrow{MQ},\overrightarrow{MP}$.\\
Calculons  $abs(\tan(t))$\\
$t=\pi-(t1+t2)$ avec $t1=\widehat{AMP}$ et  $t1=\widehat{BMQ}$.\\
On a :\\
$\tan(t1)=(2a-l)/c$ et $\tan(t2)=l/c$ donc on a :\\
$abs(\tan(t))=abs(\tan(t1+t2))=abs(2ac/(c^2-2al+l^2)=2ac/abs(l^2-2al+c^2)$\\
La condition pour que la m\'ediatrice de $MQ$ coupe le segment $PN$ est donc:\\
 $\sqrt{l^2+c^2}*abs(c^2-2al+l^2)\sqrt 3<\sqrt{l^2+c^2}(2ac)$\\
Soit :
$$abs(l^2-2al+c^2)<(2ac)/\sqrt 3 $$
Que vaut $abs(l^2-2al+c^2)$ ?\\
si $a\leq c$ le trin\^ome $x^2-2ax+c^2$ est positif ou nul donc on a :\\
$abs(l^2-2al+c^2)=l^2-2al+c^2$
si $a> c$ le trin\^ome $x^2-2ax+c^2$ a 2 racines :\\
$x_1=a-\sqrt{a^2-c^}$ et $x_2=a+\sqrt{a^2-c^}$ donc \\
si $x_1\leq l\leq x_2$ on a :\\
$abs(l^2-2al+c^2)=2al-(l^2+c^2)$
si $l<x_1$ ou si  $x_2<l$ on a :\\
$abs(l^2-2al+c^2)=l^2-2al+c^2$.
\subsection{Les conditions sur $a$ et $c$}
D'apr\`es le lemme la condition pour que $R$ soit entre $P$ et $N$ est :\\
$$abs(l^2-2al+c^2)<2ac/\sqrt 3$$
 1/ si $0<a\leq c$, puisque $l^2+c^2=4ac/\sqrt 3$  la condition est :\\
$abs(l^2-2al+c^2)=l^2-2al+c^2=4ac/\sqrt 3-2al<2ac/\sqrt 3$ soit\\
$c/\sqrt 3<l$\\
Donc $c^2/3+c^2=4c^2/3<l^2+c^2=4ac/\sqrt 3$ ce qui donne comme condition :
$$a\leq c\leq a\sqrt 3$$
2/ si $0<c\leq a$ on a $l^2-2al+c^2\geq 0 $ pour
$l\leq a-\sqrt{a^2-c^2}$ ou pour  $\a+\sqrt{a^2+c^2}\leq l$.\\
la condition est le m\^eme que dans le cas pr\'ec\'edent  soit :\\
$c/\sqrt 3<l$\\
Donc $c^2/3+c^2=4c^2/3<l^2+c^2=4ac/\sqrt 3$
 ce qui donne comme condition pour que $R$ soit entre $P$ et $N$:
$$c\leq a\sqrt 3$$
Cette conditon est v\'erifi\'ee dans ce cas puisque $c<a$
3/si $0<c\leq a$ on a $l^2-2al+c^2\leq 0 $ pour
 $a-\sqrt{a^2-c^2}\leq l \leq a+\sqrt{a^2+c^2}$ on a $l^2-2al+c^2<0$
 donc la condition devient :\\
$2al-(l^2+c^2)\leq 2ac/\sqrt 3$ soit puisque $l^2+c^2=4ac/\sqrt 3$\\
$2al-4ac/\sqrt 3\leq 2ac/\sqrt 3$
Donc $l$ doit v\'erifier la condition :\\
$l\leq c\sqrt 3$ donc \\
$4ac/\sqrt 3=l^2+c^2\leq 3c^2+c^2=4c^2$\\
ce qui donne comme condition :
$$c\leq a\leq c\sqrt 3$$
3/  si $0<c\leq a$ on a $l^2-2al+c^2\geq 0 $ pour
 $l\leq a-\sqrt{a^2-c^2}$ ou pour  $\a+\sqrt{a^2+c^2}\leq l$ 
si $l\leq a-\sqrt{a^2-c^2}$ donc $l^2+c^2\leq 2a^2-2a\sqrt{a^2-c^2}$
puisque $l^2+c^2=4ac/\sqrt 3$, on a :\\
$4ac/\sqrt 3\leq 2a^2-2a\sqrt{a^2-c^2}$ \\
$c\leq \sqrt 3(a-\sqrt{a^2-c^2}$\\
$\sqrt 3\sqrt{a^2-c^2}\leq \sqrt 3 a-c$\\
$3(a^2-c^2)\leq (3a^2+c^2-2\sqrt 3ac$\\
$\sqrt 3a\leq 2c$
la condition devient :\\
$l^2-2al+c^2=4ac/\sqrt 3-2al<2ac/\sqrt 3$ ou encore $l^2+c^2<  $
On a :\\
$l^2<2a^2-c^2-2a\sqrt{a^2-c^2}$ ou $l^2<2a^2-c^2+2a\sqrt{a^2-c^2}$ donc\\
$l^2+c^2-2al=4ac/\sqrt 3-2al<2a^2-2a\sqrt{a^2-c^2}$\\

Donc la construction de Dudeney sera valable pour les rectangles $c\times a$
soit pour $a\leq c\leq a\sqrt 3$, soit pour $c\leq a\leq c\sqrt 3$
{\bf Autre m\'ethode}\\
On demande \`a {\tt Xcas} les coodonn\'ees $xR,yR$ du point $R$.\\
Pour que $R$ soit sur le segment $PN$ il faut et il suffit que :
$0<xR<2c$ et $0<yR<2a$.\\
Pour simplifier les calculs on peut supposer que $c=1$.\\
\begin{giaconload}
  c:=1:;
  l:=sqrt(4*a*c/sqrt(3)-c^2):;
  M:=point(c):;N:=point(c+2*i*a):;
  P:=point((2*a-l)*i):;
  Q:=point(2c+i*l):;
  R:=inter_unique(droite(P,N),mediatrice(M,Q)):;
  aff:=evalc(affixe(R)):;
  xR(a):=simplify(re(aff));yR(a):=simplify(im(aff)); 
\end{giaconload}
puis \\
\giacinput{solve(xR(a)>0,a)}
\giacinput{solve(xR(a)<2,a)}
\giacinput{solve(yR(a>0,a)}
\giacinput{solve(yR(a)<2a,)}







(A:=point(0)),(B:=point(2c)),(C:=point(2c+2a*i)),(D:=point(2a*i));
polygone(A,B,C,D);
supposons(l=[0.9,0,2,0.1]);//l:=a*sqrt(4a*c/sqrt(3)-c^2);sqrt(4a*c/sqrt(3)-a^2)
P:=point(2a-l*i);Q:=point(2c+l*i);
M:=point(c);N:=point(c+2a*i);
R:=inter_unique(mediatrice(M,Q),segment(N,P));
L:=L,affichage(triangle(D,P,N),2+rempli);
L:=L,affichage(polygone(A,P,R,M),1+rempli);
L:=L,affichage(polygone(C,N,R,Q),3+rempli);
L:=L,affichage(polygone(B,M,R,Q),4+rempli);
R2:=symetrie(M,R);
P2:=symetrie(M,P);
N1:=symetrie(Q,N);
C1:=symetrie(Q,C);
R1:=symetrie(Q,R);
L:=L,affichage(polygone(C1,N1,R1,Q),3+rempli);
L:=L,affichage(polygone(B,P2,R2,M),1+rempli);
L:=L,affichage(triangle(C1,P2,N1),2+rempli);
S:=inter_unique(cercle(3/2+2*i,2),segment(B,C));
simplify(longueur2(R1,R2)), simplify(longueur2(R,R2));
B:=B;C:=C;N:=N;
